Sending a CDO email message using an SSL connection

Question

I have an asp page that sends the details of a form via email using CDO. So far, I have done this using smtp port 25 over a clear connection to a hmail server.

I now need to use an SSL connection. I have created a security certificate and set hmail server to use port 465 and ssl.

However, for some reason when I try to send the form I get an error 500 and the email is not sent.

I have tried with port 587 as well but it doesn't work either.

The CDO code I use is as follows:

If request.Form("submit") <> "" then

Set myMail=CreateObject("CDO.Message")
myMail.Subject="xxxxxxx"
myMail.From=Request.Form("email")
myMail.To= "xxxxxxxxxxx"

myMail.TextBody = "Name:"& Request.Form("name")& vbcrlf & vbcrlf & _

"Email:" & Request.Form("email") & vbcrlf & vbcrlf &  _

"Telephone:" & Request.Form("telephone") & vbcrlf & vbcrlf & _

"Location:" & Request.Form("location") & vbcrlf & vbcrlf & _

"Other location:" & Request.Form("other_location") & vbcrlf & vbcrlf & _

"Comments:" & Request.Form("comments")

myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing")=2
'Name or IP of remote SMTP server
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") _
="127.0.0.1"
'Server port
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") _
=465
MyMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
myMail.Configuration.Fields.Update
myMail.Send
set myMail=nothing

Does anyone have an idea what can be wrong?

Thank you.

Answer 1

I had the same problem working with Legacy ASP Code. The following Code works with Amazon. Note: Only Port 25 or 465 seems to work and smtpusessl = 1 (in VBScript True==-1)

' Create Connection
Function GetEmailConnection ()
    Set oMail = CreateObject("CDO.Message")
    Set GetEmailConnection = oMail
End function
Function GetConfiguration()
    Set oConfig = CreateObject("CDO.Configuration")
    Set GetConfiguration = oConfig  
End Function

' Send Email

    Sub SendEmail (subject, fromAddress, toAddress, body)
        set objMessage = GetEmailConnection()


    Set objConfiguration = GetConfiguration()

    Set fields = objConfiguration.Fields

    Const cdoSendUsingPort = 2

    With fields
    .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort 
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "email-smtp.us-east-1.amazonaws.com"
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 ' 
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'basic 
    .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password"
    .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "user"
    .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 10
    .Update
    End With
    With objMessage
    set .Configuration = objConfiguration
    .Subject = subject 
    .From = fromAddress 
    .To= toAddress
    .TextBody = body
    .Send
    End With
    set objMessage = nothing        
end Sub