NaN issue in fortran 90

fortran90 intel-fortran
JoeCoolman picture JoeCoolman · Jun 27, 2013 · Viewed 30.3k times · Source

I realize that if you write

    Real (Kind(0.d0))::x,y
    x = sqrt(-1.d0)
    y = sqrt(-1.d0)
    if (x == y) then
       write(*,*)'yep, they are equals', x
    endif

It compiles ok using ifort. But nothing is written, the conditional is always false, did you notice that? why is this so?

Answer

Jonathan Dursi picture Jonathan Dursi · Jun 28, 2013

NaN signifies not a number, and since there are many, different, reasons a calculation could give that result, they generally do not compare as equal against themselves. If you want to do nan-testing, fortran compilers that support the f2003 standard (which is recent versions of most compilers) have ieee_is_nan in the ieee_arithmetic module:

program testnan
    use ieee_arithmetic

    real (kind=kind(0.d0)) :: x,y,z

    x = sqrt(-1.d0)
    y = sqrt(-1.d0)
    z = 1.d0

    if ( ieee_is_nan(x) ) then
       write(*,*) 'X is NaN'
    endif
    if ( ieee_is_nan(y) ) then
       write(*,*) 'Y is NaN'
    endif
    if ( ieee_is_nan(x) .and. ieee_is_nan(y) ) then
       write(*,*) 'X and Y are NaN'
    endif

    if ( ieee_is_nan(z) ) then
       write(*,*) 'Z is NaN, too'
    else
       write(*,*) 'Z is a number'
    endif

end program testnan

Compiling and running this program gives

ifort -o nan nan.f90

 X is NaN
 Y is NaN
 X and Y are NaN
 Z is a number

Unfortunately, gfortran still doesn't implement ieee_arithmetic as time of writing, so with gfortran you have to use the non-standard isnan.

Related questions

Format string for output dependent on a variable

I would like to have a Fortran write statement formatted to depend on some variable. For example, I could write: write(*,'(3f15.3,3f9.2)') x,y,z,(var(i),i=1,nvari) where nvari = 3. But, what if, in some cases, …

Read More
Test whether a directory exists or not

I'm trying to verify that a directory exists using Fortan90. On various sites I found: logical :: dir_e inquire(file='./docs/.', exist=dir_e) if ( dir_e ) then write(*,*) "dir exists!" else ! workaround: it calls an extern program... …

Read More
The mysterious nature of Fortran 90 modules

Fortran 90 modules are evanescent creatures. I was using a (singular) module for a while with some success (compiling using Intel Visual Fortran and Visual Studio 2010). Then I wrote another module and tried to USE it in another function, before receiving …

Read More